AC_PREREQ([2.69])
AC_INIT([ft_ssl], [0.0.1], [])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIRS([m4])
AM_INIT_AUTOMAKE([foreign -Wall -Werror subdir-objects])

AC_PROG_CC
if test "x$ac_cv_env_CFLAGS_set" != "xset"; then
	CFLAGS="-O2"
fi

AM_PROG_AR

LT_PREREQ([2.2])
LT_INIT

PKG_PROG_PKG_CONFIG

AC_ARG_WITH([bundled-libcli],
			AS_HELP_STRING(
						   [--with-bundled-libcli],
						   [force using bundled ./libcli (ignore system)]),
						   [],
						   [with_bundled_libcli=no])

have_system_libcli=no
AS_IF([test "x$with_bundled_libcli" != "xyes"], [
	   PKG_CHECK_MODULES([LIBCLI], [libcli >= 0.1.0],
						 [have_system_libcli=yes],
						 [have_system_libcli=no]
						 )
	   ])

AM_CONDITIONAL([USE_SYSTEM_LIBCLI], [test "x$have_system_libcli" = "xyes"])
AM_CONDITIONAL([BUILD_BUNDLED_LIBCLI], [test "x$have_system_libcli" != "xyes"])

AC_SUBST([LIBCLI_CFLAGS])
AC_SUBST([LIBCLI_LIBS])

AS_IF([test "x$have_system_libcli" != "xyes"], [
	   AC_CONFIG_SUBDIRS([libcli])
	   ])

AC_CONFIG_FILES([
				 Makefile
				 src/Makefile
				 ])
AC_OUTPUT

AC_MSG_NOTICE([

  ft_ssl $VERSION
  ---------------
  prefix : $prefix
  CC     : $CC
  CFLAGS : $CFLAGS
  libcli : system=$have_system_libcli (forced bundled=$with_bundled_libcli)
])